Phân Tích Nứt Dầm Bê Tông - cốt thép

code :

finish
/clear
/title, Vi du phan tich nut dam be tong
/prep7
et,1,65 ! Phan tu be tong SOLID65 
mp,ex,1,3e7 ! E cot thep  
mp,ex,2,1e6, ! E be tong
mp,dens,2,.00025 ! Density be tong 
tb,concr,2  ! Du lieu cho phan tu be tong
tbdata,1,.3,.5,200,4000 ! He so cat, cuong do keo va nen  


r,1,1,.03,0,0 ! Vat lieu 1 (thep), 3% cot thep theo phuong x
r,2,1,.01,0,0 ! Vat lieu 1 (thep), 1%
r,3,1,.04,0,0 ! Vat lieu 1 (thep), 4%

block,,100,,5,,5 ! Tao khoi
block,,100,5,10,,5
block,,100,10,15,,5

nummrg,kp,,,,low
numcmp,volu

esize,5 ! Kich thuoc phan tu
mat,2 ! Vat lieu be tong
real,1 ! Thanh thep
vmesh,1
real,2
vmesh,2
real,3
vmesh,3

nsel,s,loc,x ! Gan dieu kien bien hai dau dam
d,all,all
nsel,s,loc,x,100
d,all,all
nsel,all
fini

/solu
nsel,s,loc,y,15  !Gan tai trong ap luc phan bo deu
sf,all,pres,100
nsel,all

outres,all,all
nsub,10
solve
fini

/post1
/device,vector,1
set,last
plcrack  ! Hien thi vi tri nut tren phan tu SOLID65
fini

Nguồn : http://hungkcct.wordpress.com/2012/02/07/ansys-vi-d%E1%BB%A5-th%E1%BB%B1c-t%E1%BA%BF-phan-tich-n%E1%BB%A9t-d%E1%BA%A7m-be-tong-c%E1%BB%91t-thep/